### Copyright (C) 1997 John D. Hardin
### This program is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### This program is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with this program; if not, write to the Free Software
### Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.

### $Id: denyptp.template,v 1.6 1999-09-14 21:55:14-07 jhardin Exp $


proc denyptp {} {
    # Deny / Services (Point-to-Point)

    Desc "Point-to-Point Services Blocking"

    ShortDesc "Point-to-Point Service Blocking"

    Header head1 -text "Point-to-Point Service Blocking"\
	    -background gray\
	    -help "Services are things like Telnet for logins, SMTP for email, FTP for file transfer,"\
	    "HTTP for Webs, and so forth. Certain services you may want to provide even if your default"\
	    "policy is \"deny\", for example, HTTP to serve web pages."\
	    "\n\nUse point-to-point rules for controlling one particular local-network computer's"\
	    "access to one particular Internet computer, or vice-versa."

    Label label1 -text "Firewall support"\
            -textafter "compiled into the kernel."\
	    -default "is"\
	    -packFrame:anchor center \
	    -help "Firewall support must be compiled into the kernel. If it is not,"\
	    "then you must configure and build a new kernel; see the Kernel HOWTO for"\
	    "instructions."

    Entry hostIP -text "Internet Host"\
            -help "The name or unique IP address of a computer on the Internet,"\
	    "or a network address (to match all hosts on a particular network).\n"\
	    "WARNING: If you enter a name then that name should probably be in your /etc/hosts file."\
	    "If you access the Internet via dialup there is no guarantee that the ipfwadm"\
            "command will be able to look up the name using DNS."\
            "\n\nIf you provide a file name here, the IP addresses and netmasks will be retrieved"\
            "from that file at the time the firewall script is run. This allows you to modify the"\
            "list of Internet hosts permitted to access your local network without having to"\
            "regenerate the firewall script; simply edit the IP address file and re-run the"\
            "generated firewall script."

    global MaskList
    ComboBox hostnetmask -text "Network Mask"\
	    -count 8 -noedit 1\
            -entries $MaskList\
	    -help "If you entered the IP address or name for a specific host, select \"32: 255.255.255.255\" -"\
	    "this means that the address must match exactly for the packet to be accepted.\n"\
	    "If you entered a network address, or if you entered a host IP or name and want to match all of the"\
	    "hosts on the same network as that host, select the appropriate netmask for that network.\n"\
	    "WARNING: If you select \"0: 0.0.0.0\" then this rule will apply to *all* hosts on the Internet."

    Entry localhostIP -text "Local Host"\
            -help "The unique IP address of a computer on the local network."

    global ServiceList
    ComboBox denyservice -text "Service to block"\
	    -count 10\
	    -help "Select a service from the list, or enter one in the form port#(:port#)/\[tcp|udp\]."\
	      "For example, to block HTTP requests, enter \"80/tcp\". See the file"\
	      "/etc/services (from which this list was generated) for a list of services with some comments,"\
	      "or consult your ISP."\
            -entries $ServiceList

    Radio direction -defaultIndex 0\
	    -entryhelp {\
	    "Inbound" "Service requests coming in from host(s) on the Internet."\
	    "Outbound" "Service requests going out to host(s) on the Internet."\
	    }

    Line line1

    Frame frame1 -entries {hostIP hostnetmask}
    Frame frame2 -entries {denyservice direction}
    Frame frame3 -entries {frame1 localhostIP frame2 line1} -orient top

    ExtEntry deniedhosts -entries frame3 -count 5

    ShowPage {
      global FirewallInKernel
      if {$FirewallInKernel == 0} {
	set label1 "is not"
	Disable deniedhosts
      } else {
	set label1 "is"
	Enable deniedhosts
      }
    }

    Save {
      global IPFWADM
      global ISPPort
      global LocalNetIP
      global LocalNetMask
      global PERL
      global ParseIP
      global MatchService
      global MatchPort
      if {$IPFWADM == "" || $ISPPort == "" || ${isp@on_internet} == 0} {
        # nothing
      } else {

        forevery deniedhosts {

          # If host IP is actually a filename, then parse the IP addresses from the file
          set fromfile 0
          if {[file exists $hostIP]} {
            if {$PERL != ""} {
              set fromfile 1
              set host "\$IP_TO_BLOCK"
              print
              print "# process P-t-P Internet host permissions from file $hostIP"
              print "if \[ -s $hostIP ]"
              print "then"
              print "  $PERL -n -e '$ParseIP' $hostIP | \\"
              print "  while read IP_TO_BLOCK"
              print "  do"
            } else {
              print
              print "# perl not found - cannot set P-t-P Internet host rules from $hostIP."
              print "# Install perl, then regenerate the firewall file."
              # generate do-nothing rules
              set host "0.0.0.0/32"
            }
          } else {
            # get the net mask for the host
            regexp {([0-9]+): } $hostnetmask junk maskbits
            set host "$hostIP/$maskbits"
          }

          set service $denyservice
          if {[regexp "$MatchPort" $service junk port junk prot]} {
            set ACK [pick {$prot == "tcp"} " \$ConnEstablished" ""]
            # if there's a description before or after the port spec, retrieve it.
            set descr ""
            if {![regexp "^(\[ A-Za-z0-9\\-_\]+)\[ \t\]+" $service junk descr]} {
              # not before. try after.
              regexp "\[ \t(\]+(\[ A-Za-z0-9\\-_\]+)" $service junk descr
            }
            if {$descr != ""} {
              set descr " ($descr)"
            }

            if {$direction(index) == 0} {	# inbound (specified host is SOURCE)
              if {$prot == "icmp"} {
                print "# Block ICMP message $port$descr from Internet host/network $host to local host $localhostIP"
                print $IPFWADM "-I -a deny -o \$INET -P $prot -S $host $port -D $localhostIP/32"
              } else {
                if {$prot == "tcp"} {
                  print "# Allow established $prot port $port$descr traffic from Internet network/host $host to local host $localhostIP"
                  print $IPFWADM "-I -a accept \$INET -P $prot \$ConnEstablished -S $host -D $localhostIP/32 $port"
                }
                print "# Block new $prot port $port$descr traffic from Internet network/host $host to local host $localhostIP"
                print $IPFWADM "-I -a deny -o \$INET -P $prot -S $hostIP/$maskbits -D $localhostIP/32 $port"
              }
            } else {				# outbound (specified host is DEST)
              if {$prot == "icmp"} {
                print "# Block ICMP message $port$descr from local host $localhostIP to Internet network/host $host"
                print $IPFWADM "-O -a reject \$INET -P $prot -S $localhostIP/32 $port -D $host"
              } else {
                if {$prot == "tcp"} {
                  print "# Allow established $prot port $port$descr traffic from local host $localhostIP to Internet network/host $host"
                  print $IPFWADM "-O -a accept \$INET -P $prot \$ConnEstablished -S $localhostIP/32 -D $host $port"
                }
                print "# Block new $prot port $port$descr traffic from local host $localhostIP to Internet network/host $host"
                print $IPFWADM "-O -a reject \$INET -P $prot -S $localhostIP/32 -D $host $port"
              }
            }

          } else {
            print "# Syntax error on host $host: service \"$denyservice\" unparseable."
            tk_dialog .warning "Warning" "Syntax error on host $host: service \"$denyservice\" unparseable." info 0 OK
          }

          if {$fromfile != 0} {
            # finish up the shell script loop
            print "  done"
            print "fi"
            print
          }
        }
      }
    }
}
