Mojo::IOLoop::Delay(3)

NAME
Mojo::IOLoop::Delay - Manage callbacks and control the flow of events

SYNOPSIS
  use Mojo::IOLoop::Delay;

  # Synchronize multiple events
  my $delay = Mojo::IOLoop::Delay->new;
  $delay->on(finish => sub { say 'BOOM!' });
  for my $i (1 .. 10) {
    my $end = $delay->begin;
    Mojo::IOLoop->timer($i => sub {
      say 10 - $i;
      $end->();
    });
  }
  $delay->wait unless Mojo::IOLoop->is_running;

  # Sequentialize multiple events
  my $delay = Mojo::IOLoop::Delay->new;
  $delay->steps(

    # First step (simple timer)
    sub {
      my $delay = shift;
      Mojo::IOLoop->timer(2 => $delay->begin);
      say 'Second step in 2 seconds.';
    },

    # Second step (concurrent timers)
    sub {
      my ($delay, @args) = @_;
      Mojo::IOLoop->timer(1 => $delay->begin);
      Mojo::IOLoop->timer(3 => $delay->begin);
      say 'Third step in 3 seconds.';
    },

    # Third step (the end)
    sub {
      my ($delay, @args) = @_;
      say 'And done after 5 seconds total.';
    }
  );
  $delay->wait unless Mojo::IOLoop->is_running;

DESCRIPTION
Mojo::IOLoop::Delay manages callbacks and controls the flow of events for Mojo::IOLoop, which can help you avoid deep nested closures that often result from continuation-passing style.

EVENTS
Mojo::IOLoop::Delay inherits all events from Mojo::EventEmitter and can emit the following new ones.

  error
  $delay->on(error => sub {
    my ($delay, $err) = @_;
    ...
  });

Emitted if an error occurs in one of the steps, breaking the chain, fatal if unhandled.

  finish
  $delay->on(finish => sub {
    my ($delay, @args) = @_;
    ...
  });

Emitted once the active event counter reaches zero and there are no more steps.

ATTRIBUTES
Mojo::IOLoop::Delay implements the following attributes.

  ioloop
  my $ioloop = $delay->ioloop;
  $delay     = $delay->ioloop(Mojo::IOLoop->new);

Event loop object to control, defaults to the global Mojo::IOLoop singleton.

METHODS
Mojo::IOLoop::Delay inherits all methods from Mojo::EventEmitter and implements the following new ones.

  begin
  my $without_first_arg = $delay->begin;
  my $with_first_arg    = $delay->begin(0);

Increment active event counter, the returned callback can be used to decrement the active event counter again. Arguments passed to the callback are queued in the right order for the next step or "finish" event and "wait" method, the first argument will be ignored by default.

  # Capture all arguments
  my $delay = Mojo::IOLoop->delay;
  Mojo::IOLoop->client({port => 3000} => $delay->begin(0));
  my ($loop, $err, $stream) = $delay->wait;

  steps
  $delay = $delay->steps(sub {...}, sub {...});

Sequentialize multiple events, the first callback will run right away, and the next one once the active event counter reaches zero. This chain will continue until there are no more callbacks, a callback does not increment the active event counter or an error occurs in a callback.

  wait
  my $arg  = $delay->wait;
  my @args = $delay->wait;

Start "ioloop" and stop it again once an "error" or "finish" event gets emitted, only works when "ioloop" is not running already.

  # Use the "finish" event to synchronize portably
  $delay->on(finish => sub {
    my ($delay, @args) = @_;
    ...
  });
  $delay->wait unless $delay->ioloop->is_running;

SEE ALSO
Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.